home *** CD-ROM | disk | FTP | other *** search
/ Libris Britannia 4 / science library(b).zip / science library(b) / DJGPP / CBGRX103.ZIP / contrib / libgrx / drivers / stdega.asm < prev    next >
Assembly Source File  |  1993-12-06  |  11KB  |  357 lines
  1. ;--------------------------------------------------------------------------
  2. ; This is file STDEGA.ASM
  3. ;
  4. ; Copyright (C) 1991 DJ Delorie, 24 Kirsten Ave, Rochester NH 03867-2954
  5. ; Copyright (C) 1992 Csaba Biegl, 820 Stirrup Dr, Nashville, TN 37221
  6. ;
  7. ; This file is distributed under the terms listed in the document
  8. ; "copying.dj", available from DJ Delorie at the address above.
  9. ; A copy of "copying.dj" should accompany this file; if not, a copy
  10. ; should be available from where this file was obtained.  This file
  11. ; may not be distributed without a verbatim copy of "copying.dj".
  12. ;
  13. ; This file is distributed WITHOUT ANY WARRANTY; without even the implied
  14. ; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  15. ;--------------------------------------------------------------------------
  16.  
  17. include grdriver.inc
  18. cseg    segment byte public 'code'
  19.     assume  cs:cseg, ds:cseg, es:cseg, ss:nothing
  20.  
  21.  
  22. ;--------------------------------------------------------------------------
  23. ; DRIVER HEADER
  24. ;  The following entries MUST match the structure and constant
  25. ;  declarations in the file 'grdriver.h' of the GRX graphics library
  26. ;  The mode word should contain the following bitfields:
  27. ;     - the GRD_NEW_DRIVER bit set for any new format driver
  28. ;     - the adapter type field should be specified
  29. ;     - the memory size field should be specified
  30. ;     - the paging mode field should be specified
  31. ;  The mode set routine will OR in the plane bitfield as it will
  32. ;  change when different color number modes are requested.
  33. ;--------------------------------------------------------------------------
  34.  
  35.     dw    offset mode_set_routine
  36.     dw    offset paging_routine
  37. mode_W  dw    GRD_NEW_DRIVER+GRD_EGA+GRD_128K+GRD_RW_64K
  38. ;
  39. ; The 'def_xx' fields are filled in by go32 from the corresponding
  40. ; fields of the 'GO32' environment variable
  41. ;
  42. def_tw  dw    80        ; text width
  43. def_th  dw    25        ; text height
  44. def_gw  dw    640        ; graphics width
  45. def_gh  dw    350        ; graphics height
  46. def_nc  dw    16        ; graphics colors
  47.     dw    offset driver_init_routine
  48.     dw    offset text_mode_table
  49.     dw    offset graphics_mode_table
  50.  
  51. ;
  52. ; Biggest text and graphics sizes
  53. ;
  54. Max_TW  equ    80
  55. Max_TH  equ    43
  56. Max_GWn equ    640        ; non interlaced!!!
  57. Max_GHn equ    350
  58. Max_GW  equ    640        ; may be interlaced
  59. Max_GH  equ    350
  60.  
  61.  
  62. ;--------------------------------------------------------------------------
  63. ; TABLE OF SUPPORTED TEXT MODES
  64. ;    - keep sorted by size
  65. ;    - end with an all 0 entry
  66. ;    - BIOS field = 0xff disables it
  67. ;    - fields:
  68. ;        width,  height, colors, BIOS#+  setup_procedure_index*256
  69. ;--------------------------------------------------------------------------
  70. text_mode_table        label word
  71.     dw    80,    25,    2,    007h +  00000h
  72.     dw    40,    25,    16,    001h +  00000h
  73.     dw    80,    25,    16,    003h +  00000h
  74.     dw    80,    43,    16,    003h +  00100h
  75.     dw    0,    0,    0,    000h +  00000h
  76.  
  77.  
  78. ;--------------------------------------------------------------------------
  79. ; TABLE OF SUPPORTED GRAPHICS MODES
  80. ;    - keep sorted first by colors then by size
  81. ;    - end with an all 0 entry
  82. ;    - BIOS field = 0xff disables it
  83. ;    - fields:
  84. ;        width,  height, colors, BIOS#+  setup_procedure_index*256
  85. ;--------------------------------------------------------------------------
  86. graphics_mode_table    label word
  87.     dw    320,    200,    16,    00dh +  00000h
  88.     dw    640,    200,    16,    00eh +  00000h
  89.     dw    640,    350,    16,    010h +  00000h
  90.     dw    0,    0,    0,    000h +  00000h
  91.  
  92.  
  93. ;--------------------------------------------------------------------------
  94. ; TABLE OF SPECIAL SETUP PROCEDURES
  95. ;  You may need such procedures for:
  96. ;     -- reloading fonts on standard EGA or VGA for
  97. ;     higher resolution text modes
  98. ;     -- enable HiColor mode of some Super VGAs
  99. ;     -- Handle the parameter passing conventions of the VESA BIOS
  100. ;     -- put VGA into 256 color plane mode ("MODE X")
  101. ;     -- etc...
  102. ;  There should be one entry in the table for every non-zero
  103. ;  'setup_procedure_index' in the text and graphics mode tables.
  104. ;  The first entry in the table belongs to index 100h, and so on.
  105. ;  The special setup procedure is invoked via a near call.
  106. ;
  107. ;  Entry: DI=address of the mode record from the text or graphics
  108. ;      table to set up.
  109. ;
  110. ;  Exit:  Adapter configured
  111. ;      BX=driver mode word as it should be returned by the mode set
  112. ;         routine. Typically it involves picking up the mode word
  113. ;         from the header and OR-ing in the appropriate bitplane mode
  114. ;         bitfield. (This is not needed for text modes)
  115. ;      AX, CX, DX, SI can be trashed, PRESERVE DI!!!!
  116. ;
  117. ;  NOTE: This runs in real mode, but don't mess with the segment registers.
  118. ;--------------------------------------------------------------------------
  119. special_setup_table    label word
  120.     dw    offset  EGA_43row_mode_set
  121.  
  122. ;
  123. ; Routine to set up VGA 50 row mode
  124. ; interface is described above
  125. ;
  126. EGA_43row_mode_set    proc    near
  127.     mov    ax,03h            ; set 80x25 mode
  128.     int    10h
  129.     xor    bx,bx
  130.     mov    ax,1112h        ; load 8x8 font
  131.     int    10h
  132.     mov    cx,0407h        ; fix up cursor
  133.     mov    ax,0100h
  134.     int    10h
  135.     ret
  136. EGA_43row_mode_set    endp
  137.  
  138.  
  139. ;--------------------------------------------------------------------------
  140. ; DRIVER INIT ROUTINE
  141. ;  called once after the driver is loaded
  142. ;  may do one or more of the followings:
  143. ;    - check for proper board type
  144. ;    - check amount of RAM on board, and:
  145. ;    -- update word in header to reflect correct amount
  146. ;    -- disable modes in the tables for which there is not enough RAM
  147. ;    - check for special equipment (HiColor DAC, etc...)
  148. ;
  149. ;  Entry: nothing
  150. ;
  151. ;  Exit:  AX=status:
  152. ;       non-zero: OK,
  153. ;       0: something went wrong (e.g. wrong adapter, etc..)
  154. ;      BX,CX,DX may be trashed
  155. ;
  156. ;  NOTE: This runs in real mode, but don't mess with the segment registers.
  157. ;--------------------------------------------------------------------------
  158. driver_init_routine    proc    far
  159.     mov    ax,1
  160.     ret
  161. driver_init_routine    endp
  162.  
  163.  
  164. ;--------------------------------------------------------------------------
  165. ; MODE SET ROUTINE
  166. ;  sets up a text or graphics mode as close as possible to the one
  167. ;  reguested by the user with regard to number of colors and size.
  168. ;
  169. ;  Entry: AX=mode selection
  170. ;     0 = 80x25 text
  171. ;     1 = default text
  172. ;     2 = text CX cols by DX rows
  173. ;     3 = biggest text
  174. ;     4 = 320x200 graphics
  175. ;     5 = default graphics
  176. ;     6 = graphics CX width by DX height
  177. ;     7 = biggest non-interlaced graphics
  178. ;     8 = biggest graphics
  179. ;     9 = graphics BX colors, CX width by DX height
  180. ;
  181. ;  Exit: BX=driver mode flag
  182. ;     CX=width (in pixels or characters)
  183. ;     DX=height
  184. ;
  185. ;  NOTE: This runs in real mode, but don't mess with the segment registers.
  186. ;     YOU SHOULD NOT NEED TO CHANGE THIS ROUTINE AS IT IS PRETTY
  187. ;     MUCH TABLE DRIVEN
  188. ;--------------------------------------------------------------------------
  189. mode_set_routine    proc    far
  190.     push    ds
  191.     push    di
  192.     push    si
  193.     mov    si,cs
  194.     mov    ds,si
  195.     cmp    ax,9
  196.     jbe    DoIt
  197.     jmp    Exit
  198. DoIt:    add    ax,ax
  199.     mov    si,ax
  200.     jmp    WORD PTR mode_set_table[si]
  201. mode_set_table  label    word
  202.     dw    offset mode_0
  203.     dw    offset mode_1
  204.     dw    offset mode_2
  205.     dw    offset mode_3
  206.     dw    offset mode_4
  207.     dw    offset mode_5
  208.     dw    offset mode_6
  209.     dw    offset mode_7
  210.     dw    offset mode_8
  211.     dw    offset mode_9
  212. mode_0: mov    si,offset text_mode_table    ; 80x25 text
  213.     mov    bx,def_nc
  214.     mov    cx,80
  215.     mov    dx,25
  216.     jmp    Lookup
  217. mode_1: mov    si,offset text_mode_table    ; default text
  218.     mov    bx,def_nc
  219.     mov    cx,def_tw
  220.     mov    dx,def_th
  221.     jmp    Lookup
  222. mode_2: mov    si,offset text_mode_table    ; CX*DX text
  223.     mov    bx,def_nc
  224.     jmp    Lookup
  225. mode_3: mov    si,offset text_mode_table    ; biggest text
  226.     mov    bx,def_nc
  227.     mov    cx,Max_TW
  228.     mov    dx,Max_TH
  229.     jmp    Lookup
  230. mode_4: mov    si,offset graphics_mode_table    ; 320x200 graphics
  231.     mov    bx,def_nc
  232.     mov    cx,320
  233.     mov    dx,200
  234.     jmp    Lookup
  235. mode_5: mov    si,offset graphics_mode_table    ; default graphics
  236.     mov    bx,def_nc
  237.     mov    cx,def_gw
  238.     mov    dx,def_gh
  239.     jmp    Lookup
  240. mode_6: mov    si,offset graphics_mode_table    ; CX*DX graphics
  241.     mov    bx,def_nc
  242.     jmp    Lookup
  243. mode_7: mov    si,offset graphics_mode_table    ; biggest non-interlaced gr
  244.     mov    bx,def_nc
  245.     mov    cx,Max_GWn
  246.     mov    dx,Max_GHn
  247.     jmp    Lookup
  248. mode_8: mov    si,offset graphics_mode_table    ; biggest graphics
  249.     mov    bx,def_nc
  250.     mov    cx,Max_GW
  251.     mov    dx,Max_GH
  252.     jmp    Lookup
  253. mode_9: mov    si,offset graphics_mode_table    ; CX*DX graphics w/ BX colors
  254. ;
  255. ; At this point:
  256. ;   SI points to the table to search (text or graphics)
  257. ;   BX has colors
  258. ;   CX has width
  259. ;   DX has height
  260. ;
  261. Lookup: xor    ax,ax                ; last color number seen
  262. Find_C: cmp    [si+4],ax            ; last color number == this?
  263.     je    Same_C
  264.     jb    Prev_C                ; end of table -- use last color
  265.     cmp    BYTE PTR [si+6],0ffh        ; valid entry ?
  266.     je    Prev_C                ; not -- use last color
  267.     mov    ax,[si+4]            ; record color number
  268.     mov    di,si                ; start of entries w/ this color
  269.     cmp    ax,bx                ; enough colors ?
  270.     jae    Find_S
  271. Same_C: add    si,8
  272.     jmp    Find_C
  273. Prev_C: or    ax,ax                ; found any color at all?
  274.     je    Exit
  275. ;
  276. ; At this point:
  277. ;   DI points into the table to the first entry with the desired color
  278. ;      number (either it has enough colors or it is the highest color
  279. ;      number supported by the driver). Additionally, at least the
  280. ;      first (= smallest size) entry for this color is valid (has a
  281. ;      valid BIOS number).
  282. ;   AX has the color number adjusted for the driver
  283. ;   CX has width
  284. ;   DX has height
  285. ;
  286. Find_S: cmp    [di+4],ax            ; still the same color #?
  287.     jne    Prev_S
  288.     cmp    BYTE PTR [di+6],0ffh        ; valid entry ?
  289.     je    Prev_S
  290.     cmp    [di],cx
  291.     jb    Next_S
  292.     cmp    [di+2],dx
  293.     jae    GotIt
  294. Next_S: add    di,8
  295.     jmp    Find_S
  296. Prev_S: sub    di,8
  297. ;
  298. ; At this point:
  299. ;   DI points to the table entry we want to set up
  300. ;
  301. GotIt:  mov    ax,[di+6]            ; BIOS mode number
  302.     or    ah,ah                ; special ?
  303.     je    doBIOS
  304.     mov    al,ah
  305.     xor    ah,ah
  306.     dec    ax
  307.     add    ax,ax
  308.     mov    si,ax
  309.     call    WORD PTR special_setup_table[si]
  310.     jmp    RetVal
  311. doBIOS: int    10h
  312.     mov    bx,GRD_1_PLANE
  313.     cmp    WORD PTR [di+4],2        ; 2 colors ?
  314.     je    doFLAG
  315.     mov    bx,GRD_4_PLANES
  316.     cmp    WORD PTR [di+4],16        ; 16 colors ?
  317.     je    doFLAG
  318.     mov    bx,GRD_8_PLANES
  319.     cmp    WORD PTR [di+4],256        ; 256 colors ?
  320.     je    doFLAG
  321.     mov    bx,GRD_16_PLANES
  322.     cmp    WORD PTR [di+4],32768        ; 32K colors ?
  323.     je    doFLAG
  324.     mov    bx,GRD_PLANE_MASK        ; something is wrong!!
  325. doFLAG: or    bx,mode_W
  326. RetVal: mov    cx,[di]
  327.     mov    dx,[di+2]
  328. Exit:    pop    si
  329.     pop    di
  330.     pop    ds
  331.     ret
  332. mode_set_routine    endp
  333.  
  334.  
  335. ;--------------------------------------------------------------------------
  336. ; PAGING ROUTINE
  337. ;
  338. ;  Entry: AH=read page
  339. ;      AL=write page
  340. ;
  341. ;  Exit: VGA configured.
  342. ;     AX,BX,CX,DX,SI,DI may be trashed
  343. ;
  344. ;  NOTE: This runs in protected mode!  Don't mess with the segment registers!
  345. ;     This code must be relocatable and may not reference any data!
  346. ;--------------------------------------------------------------------------
  347.     assume  ds:nothing, es:nothing
  348.  
  349. paging_routine  proc    far
  350.     ret
  351. paging_routine  endp
  352.  
  353.  
  354. cseg    ends
  355.     end
  356.  
  357.